  ;REMARK: edit the path for the .dat file (should be same as BLIST.DEF
  ;REMARK: the [40] is the minimum security level you want to have access to
  ;REMARK:  the bbs listing utility, have this suit your security organization
"c:\rbbs\question\BBSLIST.DAT",40
:INTRO
*
*This utility is to allow you to add the number of your favorite BBS to
*a database list available either here or in the EarthWorld Bulletins
*section for perusal by other users. You will be asked several
*questions for which you should be prepared. These include the following
*information on the BBS you'll be adding: name, phone number (w/area code),
*sysop's name, software the board uses (ex.WildCat, RBBS, Spitfire, etc.),
*the board's hours of operation, the maximum baud rate supported, and a
*brief description of the BBS environment (i.e. aimed at political debate,
*environmental issues, support board for certain software, carries certain
*networks, conferences, etc.)
*
:TOPMENU
?A)dd an entry, L)ist current numbers, Q)uit to EarthWorld
=AADD=LLISTTEXT=QQUIT= QUESTION2E
:MENU2
*Please respond with A, L, or Q
>TOPMENU
:ADD
*            x---------------------------------x
?1Name of BBS
*              xxx-xxx-xxxx
?2Phone number
*             x---------------------------------------x
?3Sysop's name
*         x----x
?4BBS type
*                   x------------x
?5Hours of operation
*          x-------x
?6Baud rate
*Please describe this bbs,i.e. special conferences,networks,software,etc:
* (you have three lines for this, please make an entry on each line)
?7.
?8.
?9.
:DISPLAY
*-----------------------------------------------------------------------
*
* 1. Name of BBS: [1]                         
*
* 2. Phone number: [2]                               
*
* 3. Sysop's name: [3]                               
*
* 4. BBS type: [4]           
*
* 5. Hours of operation: [5]          
*
* 6. Baud rate supported: [6]         
*
*    Notes:
*
* 7. [7]                                                                 
* 8. [8]                                                                 
* 9. [9]                                                                 
*-----------------------------------------------------------------------
:MIDMENU
?Is this information all correct (Y,N)
=YAPPEND=NEDIT= DISPLAY
:APPEND
  ;REMARK: be sure the path to the macros directory suits your system
M C:\RBBS\MACROS\LST.MCR
*
*Thank you for your contribution to this list! Feel free to peruse the
*listing either here in the list utility or in the EarthWorld Bulletin
*section, Bulletin # 53.
*
*
>TOPMENU
:EDIT
* Item you'd like to change ?
? (A)ll, 1, 2, 3, 4, 5, 6, 7, 8, 9, N)one-Leave as is, Q)uit)
=AADD=1ONE=2TWO=3THREE=4FOUR=5FIVE=6SIX=7SEVEN=8EIGHT=9NINE=NAPPEND=QQUIT= DISPLAY
:ONE
*            x---------------------------------x
?1Name of BBS
>DISPLAY
:TWO
*              xxx-xxx-xxxx
?2Phone number
>DISPLAY
:THREE
*             x---------------------------------------x
?3Sysop's name
>DISPLAY
:FOUR
*         x----x
?4BBS type
>DISPLAY
:FIVE
*                   x------------x
?5Hours of operation
>DISPLAY
:SIX
*          x-------x
?6Baud rate
>DISPLAY
:SEVEN
*Please describe this bbs,i.e. special conferences,networks,software,etc:
?7
>DISPLAY
:EIGHT
?8
>DISPLAY
:NINE
?9
>DISPLAY
:LISTTEXT
  ;REMARK be sure the path matches your system's directory
M C:\RBBS\MACROS\LST2.MCR
>TOPMENU
:QUIT
@
